Material Dictionary 8/Material Dictionary 8.iso/sozai.exe/sozai.DXR/00121.ls

Text File | 1996-01-05 | 5.6 KB | 246 lines

on startMovie
  if the castType of cast 941 = #empty then
    set msg to "ïKóvÇ»ÉtÉ@ÉCÉãÇ™å©Ç¬Ç©ÇËÇ‹ÇþÇÒÅB" & RETURN & "CD-ROMÇ©ÇÁé¿çsǵǃǍÇæÇŽÇ¢ÅB"
    alert(msg)
    go("End")
  end if
end

on setup
  global pictsp, scrollthumbsp, scrolltop, scrollmax, firstv
  set pictsp to 1
  set scrollthumbsp to 12
  set scrolltop to 0
  set h to the height of cast the castNum of sprite pictsp
  set scrollmax to integer((h / float(75 + 26)) + 0.5) - 4
  set firstv to the locV of sprite pictsp
end

on keyhandler
  if not (the controlDown) then
    dontPassEvent()
  end if
  if the controlDown and ((the key = "c") or (the key = "C")) then
    set the text of cast "Selection" to the selection
    copyToClipBoard(cast "Selection")
    dontPassEvent()
  end if
end

on stopMovie
  set the text of cast "FilePath" to " "
  set the text of cast "Selection" to " "
end

on m2w path
  repeat with i = 1 to the maxinteger
    set c to char i of path
    if c = EMPTY then
      exit repeat
    end if
    if c = ":" then
      put "\" into char i of path
    end if
  end repeat
  return path
end

on w2m path
  repeat with i = 1 to the maxinteger
    set c to char i of path
    if c = EMPTY then
      exit repeat
    end if
    if c = "\" then
      put ":" into char i of path
    end if
  end repeat
  return path
end

on scrolldown
  global scrolltop, scrollmax
  if (scrolltop - 1) < 0 then
    exit
  end if
  set scrolltop to scrolltop - 1
  updatethumb()
  adjustselect(-1)
  updatepict()
end

on pagedown
  global scrolltop, scrollmax
  if scrolltop = 0 then
    exit
  end if
  set tscrolltop to scrolltop - 4
  if tscrolltop < 0 then
    set tscrolltop to 0
  end if
  adjustselect(tscrolltop - scrolltop)
  set scrolltop to tscrolltop
  updatethumb()
  indicate()
  updatepict()
end

on scrollup
  global scrolltop, scrollmax
  if (scrolltop + 1) > scrollmax then
    exit
  end if
  set scrolltop to scrolltop + 1
  updatethumb()
  adjustselect(1)
  updatepict()
end

on pageup
  global scrolltop, scrollmax
  if scrolltop = scrollmax then
    exit
  end if
  set tscrolltop to scrolltop + 4
  if tscrolltop > scrollmax then
    set tscrolltop to scrollmax
  end if
  adjustselect(tscrolltop - scrolltop)
  set scrolltop to tscrolltop
  updatethumb()
  indicate()
  updatepict()
end

on adjustselect delta
  set nv to the locV of sprite 19 - (delta * 101)
  if (nv < 20) or (nv > 400) then
    deselect()
  else
    set the locV of sprite 19 to nv
  end if
end

on updatethumb
  global pictsp, scrollthumbsp, scrolltop, scrollmax
  set basesp to scrollthumbsp - 1
  set len to the height of sprite basesp - the height of sprite scrollthumbsp
  set pos to scrolltop * len / scrollmax
  set the locV of sprite scrollthumbsp to the locV of sprite basesp + pos
  updateStage()
end

on thumbpressed ov
  global pictsp, scrollthumbsp, scrolltop, scrollmax
  set cn to the castNum of sprite scrollthumbsp
  set the castNum of sprite scrollthumbsp to cn + 1
  set basesp to scrollthumbsp - 1
  set h to the height of sprite scrollthumbsp
  set lastv to the locV of sprite scrollthumbsp
  set dv to the mouseV - ov
  updateStage()
  repeat while the stillDown
    set nv to the mouseV - dv
    if nv < the top of sprite basesp then
      set nv to the top of sprite basesp
    end if
    if nv > (the bottom of sprite basesp - h) then
      set nv to the bottom of sprite basesp - h
    end if
    if the mouseV < (the top of sprite basesp - 100) then
      set nv to lastv
    end if
    if the mouseV > (the bottom of sprite basesp + 100) then
      set nv to lastv
    end if
    if the mouseH < (the left of sprite basesp - 30) then
      set nv to lastv
    end if
    if the mouseH > (the right of sprite basesp + 30) then
      set nv to lastv
    end if
    set the locV of sprite scrollthumbsp to nv
    updateStage()
    indicate()
  end repeat
  deselect()
  set scrolltop to thumbindex()
  updatethumb()
  indicateoff()
  updatepict()
  set the castNum of sprite scrollthumbsp to cn
  updateStage()
end

on deselect
  set the text of cast "FilePath" to " "
  set the selStart to 0
  set the selEnd to 0
  out(19)
  updateStage()
end

on indicate
  set topone to (thumbindex() * 5) + 1
  set the text of cast "Indicator" to topone & "-" & topone + 20 - 1
end

on indicateoff
  set the text of cast "Indicator" to " "
end

on thumbindex
  global pictsp, scrollthumbsp, scrolltop, scrollmax
  set basesp to scrollthumbsp - 1
  set len to the height of sprite basesp - the height of sprite scrollthumbsp
  set pos to the locV of sprite scrollthumbsp - the locV of sprite basesp
  return ((pos * scrollmax) + (len / 2)) / len
end

on updatepict
  global pictsp, firstv, scrolltop
  startTimer()
  set the locV of sprite pictsp to firstv - (scrolltop * 101)
  updateStage()
  if the optionDown then
    exit
  end if
  repeat while the timer < 10
    nothing()
  end repeat
  if the controlDown then
    repeat while the timer < 15
      nothing()
    end repeat
  end if
end

on in sp
  if the locH of sprite sp < 0 then
    set the locH of sprite sp to the locH of sprite sp + 3000
  end if
end

on out sp
  if the locH of sprite sp > 0 then
    set the locH of sprite sp to the locH of sprite sp - 3000
  end if
end

on buttondown
  set cn to the castNum of sprite the clickOn
  set the castNum of sprite the clickOn to cn + 1
  updateStage()
  repeat while the stillDown
    if rollOver(the clickOn) then
      set the castNum of sprite the clickOn to cn + 1
    else
      set the castNum of sprite the clickOn to cn
    end if
    updateStage()
  end repeat
  set the castNum of sprite the clickOn to cn
  updateStage()
  return rollOver(the clickOn)
end